refactor!: change repo directory structure for ocaml

6 files changed, 130 insertions, 0 deletions

diff --git a/ocaml/lib/year2025/day02/part01/id.ml b/ocaml/lib/year2025/day02/part01/id.ml
new file mode 100644
index 0000000..b7a3bd2
--- /dev/null
+++ b/ocaml/lib/year2025/day02/part01/id.ml
@@ -0,0 +1,16 @@
+module ID = struct
+  (** *)
+  type t = int
+
+  let create num = num
+
+  let validate rules id = List.fold_left (fun acc r -> acc && r id) true rules
+
+  let incr = ( + ) 1
+
+  let to_int id = id
+
+  let to_string = string_of_int
+
+  let pp id = "ID=" ^ string_of_int id
+end
diff --git a/ocaml/lib/year2025/day02/part01/id.mli b/ocaml/lib/year2025/day02/part01/id.mli
new file mode 100644
index 0000000..63d5942
--- /dev/null
+++ b/ocaml/lib/year2025/day02/part01/id.mli
@@ -0,0 +1,22 @@
+module ID : sig
+  (** [t] is a ID within a range *)
+  type t
+
+  val create : int -> t
+  (** [create num] is an ID [t] *)
+
+  val validate : (t -> bool) list -> t -> bool
+  (** [validate rules id] is [true] if the [id] passes all rule checks *)
+
+  val incr : t -> t
+  (** [incr id] is the next [id] in the sequence *)
+
+  val to_int : t -> int
+  (** [to_int id] is an integer representation of [id] *)
+
+  val to_string : t -> string
+  (** [to_string id] is an string representation of [id] *)
+
+  val pp : t -> string
+  (** [pp id] is a pretty string representing [id] *)
+end
diff --git a/ocaml/lib/year2025/day02/part01/range.ml b/ocaml/lib/year2025/day02/part01/range.ml
new file mode 100644
index 0000000..ba27568
--- /dev/null
+++ b/ocaml/lib/year2025/day02/part01/range.ml
@@ -0,0 +1,18 @@
+open Id
+
+module Range = struct
+  type t = ID.t * ID.t
+
+  let create (id1, id2) = (ID.create id1, ID.create id2)
+
+  let rec collect range = collect_range_aux [] range
+
+  and collect_range_aux lst (id1, id2) =
+    match id1 <= id2 with
+    | false ->
+        lst
+    | true ->
+        collect_range_aux (id1 :: lst) (ID.incr id1, id2)
+
+  let pp (id1, id2) = "(L" ^ ID.pp id1 ^ ", R" ^ ID.pp id2 ^ ")"
+end
diff --git a/ocaml/lib/year2025/day02/part01/range.mli b/ocaml/lib/year2025/day02/part01/range.mli
new file mode 100644
index 0000000..e525e43
--- /dev/null
+++ b/ocaml/lib/year2025/day02/part01/range.mli
@@ -0,0 +1,15 @@
+open Id
+
+module Range : sig
+  (** [t] is a range of values *)
+  type t
+
+  val create : int * int -> t
+  (** [create (s, e)] is a range starting at [s] and ending at [e]. *)
+
+  val collect : t -> ID.t list
+  (** [collect r] is a list containing all elements within the range (inclusive). *)
+
+  val pp : t -> string
+  (** [pp r] is a pretty string representing [r] *)
+end
diff --git a/ocaml/lib/year2025/day02/part01/solver.ml b/ocaml/lib/year2025/day02/part01/solver.ml
new file mode 100644
index 0000000..417aa0d
--- /dev/null
+++ b/ocaml/lib/year2025/day02/part01/solver.ml
@@ -0,0 +1,55 @@
+open Id
+open Range
+
+let err_empty_input = "input is empty"
+
+(** [input_to_lines input] is a list of strings that have been split on ','.
+    Example: [input_to_lines "12-34,56-78,90-100"] becomes the list \[ "12-34"; "56-78"; "90-100" \].
+    Requires: [input] to be a string in the format "12-34,56-78,90-100". *)
+let input_to_lines input = input |> String.trim |> String.split_on_char ','
+
+let pp_lines = Seq.iter (fun l -> Logs.debug (fun m -> m "line=%s" l))
+
+(** [lines_to_ranges line] is a list of [Range]s found on [line]. *)
+let lines_to_ranges =
+  Seq.map (fun line ->
+      Scanf.sscanf line "%d-%d" (fun id1 id2 -> Range.create (id1, id2)) )
+
+let pp_ranges = Seq.iter (fun r -> Logs.debug (fun m -> m "%s" (Range.pp r)))
+
+(** [collect_all ranges] is an unsorted list of [ID]s within the [ranges] (inclusive). *)
+let collect_all =
+  Seq.concat_map (fun range -> List.to_seq (Range.collect range))
+
+let pp_collection = Seq.iter (fun c -> Logs.debug (fun m -> m "%s" (ID.pp c)))
+
+(** [rules] is a list of rules that [ID]s must pass to be considered invalid. *)
+let rules =
+  [ (fun id -> String.length (ID.to_string id) mod 2 = 0)
+  ; (fun id ->
+      let id' = ID.to_string id in
+      let id_len = String.length id' in
+      let left = String.sub id' 0 (id_len / 2) in
+      let right = String.sub id' (id_len / 2) (id_len / 2) in
+      String.equal left right ) ]
+
+(** [is_invalid id] is [true] for an [id] that passes all of the rules and is considered invalid. *)
+let is_invalid = ID.validate rules
+
+(** [passthrough_with_logs logger lst] is [lst] with the side-effects caused by calling [logger] on [lst]. *)
+let passthrough_with_logs logger lst = logger lst ; lst
+
+let solve input () =
+  if input = "" then Error err_empty_input
+  else
+    let answer =
+      input |> input_to_lines |> List.to_seq
+      |> passthrough_with_logs pp_lines
+      |> lines_to_ranges
+      |> passthrough_with_logs pp_ranges
+      |> collect_all
+      |> passthrough_with_logs pp_collection
+      |> Seq.filter is_invalid
+      |> Seq.fold_left (fun acc id -> acc + ID.to_int id) 0
+    in
+    Ok answer
diff --git a/ocaml/lib/year2025/day02/part01/solver.mli b/ocaml/lib/year2025/day02/part01/solver.mli
new file mode 100644
index 0000000..8a8eb32
--- /dev/null
+++ b/ocaml/lib/year2025/day02/part01/solver.mli
@@ -0,0 +1,4 @@
+val solve : string -> unit -> (int, string) result
+(** [solve input ()] is the solution for the first part of the second day of advent of code 2025 for [input].
+    The solution for an empty input is [Error msg].
+    Requires: [input] to be a string. *)