refactor!: change repo directory structure for ocaml

3 files changed, 133 insertions, 0 deletions

diff --git a/ocaml/lib/year2025/day01/part01/dial.ml b/ocaml/lib/year2025/day01/part01/dial.ml
new file mode 100644
index 0000000..6b531f4
--- /dev/null
+++ b/ocaml/lib/year2025/day01/part01/dial.ml
@@ -0,0 +1,76 @@
+module Dial : sig
+  (** [t] is a dial between 0 and 99 inclusive *)
+  type t
+
+  (** [direction] is a direction the dial can be turned *)
+  type direction = Left of int | Right of int
+
+  val start : t
+  (** [start] is the initial state of the dial *)
+
+  val dial_out_of_range : string
+  (** [dial_out_of_range] is the error message when the dial is out of range *)
+
+  val turn : t -> direction -> t
+  (** [turn current direction] is the new state of the dial after turning [direction] from [current] *)
+
+  val to_string : t -> string
+  (** [to_string t] is the string representation of [t] *)
+
+  val to_int : t -> int
+  (** [to_int t] is the integer representation of [t] *)
+
+  val pp_direction : direction -> string
+end = struct
+  (** [t] is an int between 0 and 99 inclusive *)
+  type t = int
+
+  type direction = Left of int | Right of int
+
+  let start = 50
+
+  let dial_out_of_range = "dial out of range"
+
+  (** [next n] is the new state of the dial after turning [Right].
+      Raises: [dial_out_of_range] if [n] is greater than 99. *)
+  let next = function
+    | n when n < 99 ->
+        n + 1
+    | 99 ->
+        0
+    | _ ->
+        failwith dial_out_of_range
+
+  (** [prev n] is the new state of the dial after turning [Left].
+      Raises: [dial_out_of_range] if [n] is less than 0. *)
+  let prev = function
+    | n when n > 0 ->
+        n - 1
+    | 0 ->
+        99
+    | _ ->
+        failwith dial_out_of_range
+
+  (** [turn current direction] is the new state of the dial after turning [direction] from [current].
+      Raises: [dial_out_of_range] if the dial is moved to an invalid state. *)
+  let rec turn current direction =
+    match direction with
+    | Left 0 ->
+        current
+    | Left n ->
+        turn (prev current) (Left (n - 1))
+    | Right 0 ->
+        current
+    | Right n ->
+        turn (next current) (Right (n - 1))
+
+  let to_string = string_of_int
+
+  let to_int t = t
+
+  let pp_direction = function
+    | Left n ->
+        "Left " ^ string_of_int n
+    | Right n ->
+        "Right " ^ string_of_int n
+end
diff --git a/ocaml/lib/year2025/day01/part01/solver.ml b/ocaml/lib/year2025/day01/part01/solver.ml
new file mode 100644
index 0000000..f4f0dde
--- /dev/null
+++ b/ocaml/lib/year2025/day01/part01/solver.ml
@@ -0,0 +1,53 @@
+open Dial
+
+let err_empty_input = "input is empty"
+
+let rec input_to_lines input =
+  let lines =
+    String.split_on_char '\n' input |> List.filter (fun l -> l <> "")
+  in
+  pp_lines lines ; lines
+
+and pp_lines = function
+  | [] ->
+      ()
+  | h :: t ->
+      Logs.debug (fun m -> m "Line=%s" h) ;
+      pp_lines t
+
+let parse_line line =
+  Scanf.sscanf line "%c%d" (fun d n ->
+      match d with
+      | 'L' ->
+          Dial.Left n
+      | 'R' ->
+          Dial.Right n
+      | _ ->
+          failwith "invalid direction" )
+
+let lines_to_turns =
+  List.map (fun (l : string) ->
+      Logs.debug (fun m -> m "parsing %s into turn" l) ;
+      let turn = parse_line l in
+      Logs.debug (fun m -> m "%s" (Dial.pp_direction turn)) ;
+      turn )
+
+let rec turn_aux count current = function
+  | [] ->
+      count
+  | h :: t ->
+      let current' = Dial.turn current h in
+      Logs.debug (fun m -> m "dial at %d" (Dial.to_int current')) ;
+      if Dial.to_int current' = 0 then turn_aux (count + 1) current' t
+      else turn_aux count current' t
+
+let turn current = turn_aux 0 current
+
+let solve input () =
+  if input = "" then Error err_empty_input
+  else
+    let lines = input_to_lines input in
+    let turns = lines_to_turns lines in
+    let start = Dial.start in
+    let answer = turn start turns in
+    Ok answer
diff --git a/ocaml/lib/year2025/day01/part01/solver.mli b/ocaml/lib/year2025/day01/part01/solver.mli
new file mode 100644
index 0000000..2eecf19
--- /dev/null
+++ b/ocaml/lib/year2025/day01/part01/solver.mli
@@ -0,0 +1,4 @@
+val solve : string -> unit -> (int, string) result
+(** [solve input ()] is the solution for the first part of the first day of advent of code 2025 for [input].
+    The solution for an empty input is [None].
+    Requires: [input] to be a multiline string using `\n` as it's line separator. *)