From 976048a85403fbb0751c34fa42703a3c47f6e918 Mon Sep 17 00:00:00 2001
From: DJ O'Leary <dijitol@proton.me>
Date: Sat, 27 Jun 2026 00:11:43 +0200
Subject: refactor!: change repo directory structure for ocaml

---
 ocaml/lib/year2025/day01/part02/dial.ml    | 68 ++++++++++++++++++++++++++++++
 ocaml/lib/year2025/day01/part02/solver.ml  | 56 ++++++++++++++++++++++++
 ocaml/lib/year2025/day01/part02/solver.mli |  4 ++
 ocaml/lib/year2025/day01/part02/turner.ml  | 28 ++++++++++++
 4 files changed, 156 insertions(+)
 create mode 100644 ocaml/lib/year2025/day01/part02/dial.ml
 create mode 100644 ocaml/lib/year2025/day01/part02/solver.ml
 create mode 100644 ocaml/lib/year2025/day01/part02/solver.mli
 create mode 100644 ocaml/lib/year2025/day01/part02/turner.ml

(limited to 'ocaml/lib/year2025/day01/part02')

diff --git a/ocaml/lib/year2025/day01/part02/dial.ml b/ocaml/lib/year2025/day01/part02/dial.ml
new file mode 100644
index 0000000..e061d6d
--- /dev/null
+++ b/ocaml/lib/year2025/day01/part02/dial.ml
@@ -0,0 +1,68 @@
+module Dial : sig
+  (** [t] is a dial between 0 and 99 inclusive *)
+  type t
+
+  (** [direction] is a direction the dial can be turned *)
+  type direction = Left of int | Right of int
+
+  val start : t
+  (** [start] is the initial state of the dial *)
+
+  val dial_out_of_range : string
+  (** [dial_out_of_range] is the error message when the dial is out of range *)
+
+  val prev : t -> t
+
+  val next : t -> t
+
+  val is_zero : t -> bool
+
+  val to_string : t -> string
+  (** [to_string t] is the string representation of [t] *)
+
+  val to_int : t -> int
+  (** [to_int t] is the integer representation of [t] *)
+
+  val pp_direction : direction -> string
+end = struct
+  (** [t] is an int between 0 and 99 inclusive *)
+  type t = int
+
+  type direction = Left of int | Right of int
+
+  let start = 50
+
+  let dial_out_of_range = "dial out of range"
+
+  (** [next n] is the new state of the dial after turning [Right].
+      Raises: [dial_out_of_range] if [n] is greater than 99. *)
+  let next = function
+    | n when n < 99 ->
+        n + 1
+    | 99 ->
+        0
+    | _ ->
+        failwith dial_out_of_range
+
+  (** [prev n] is the new state of the dial after turning [Left].
+      Raises: [dial_out_of_range] if [n] is less than 0. *)
+  let prev = function
+    | n when n > 0 ->
+        n - 1
+    | 0 ->
+        99
+    | _ ->
+        failwith dial_out_of_range
+
+  let is_zero = function 0 -> true | _ -> false
+
+  let to_string = string_of_int
+
+  let to_int t = t
+
+  let pp_direction = function
+    | Left n ->
+        "Left " ^ string_of_int n
+    | Right n ->
+        "Right " ^ string_of_int n
+end
diff --git a/ocaml/lib/year2025/day01/part02/solver.ml b/ocaml/lib/year2025/day01/part02/solver.ml
new file mode 100644
index 0000000..452209f
--- /dev/null
+++ b/ocaml/lib/year2025/day01/part02/solver.ml
@@ -0,0 +1,56 @@
+open Dial
+open Turner
+
+let err_empty_input = "input is empty"
+
+let rec input_to_lines input =
+  let lines =
+    String.split_on_char '\n' input |> List.filter (fun l -> l <> "")
+  in
+  pp_lines lines ; lines
+
+and pp_lines = function
+  | [] ->
+      ()
+  | h :: t ->
+      Logs.debug (fun m -> m "Line=%s" h) ;
+      pp_lines t
+
+let parse_line line =
+  Scanf.sscanf line "%c%d" (fun d n ->
+      match d with
+      | 'L' ->
+          Dial.Left n
+      | 'R' ->
+          Dial.Right n
+      | _ ->
+          failwith "invalid direction" )
+
+let lines_to_turns =
+  List.map (fun (l : string) ->
+      Logs.debug (fun m -> m "parsing %s into turn" l) ;
+      let turn = parse_line l in
+      Logs.debug (fun m -> m "%s" (Dial.pp_direction turn)) ;
+      turn )
+
+let rec turn_aux count dial = function
+  | [] ->
+      count
+  | h :: t -> (
+      let dial_and_count = Turner.turn dial count h in
+      match dial_and_count with
+      | dial', count' ->
+          Logs.debug (fun m ->
+              m "(dial=%d, count=%d)" (Dial.to_int dial') count' ) ;
+          turn_aux count' dial' t )
+
+let turn current = turn_aux 0 current
+
+let solve input () =
+  if input = "" then Error err_empty_input
+  else
+    let lines = input_to_lines input in
+    let turns = lines_to_turns lines in
+    let start = Dial.start in
+    let answer = turn start turns in
+    Ok answer
diff --git a/ocaml/lib/year2025/day01/part02/solver.mli b/ocaml/lib/year2025/day01/part02/solver.mli
new file mode 100644
index 0000000..9e9a2f2
--- /dev/null
+++ b/ocaml/lib/year2025/day01/part02/solver.mli
@@ -0,0 +1,4 @@
+val solve : string -> unit -> (int, string) result
+(** [solve input ()] is the solution for the second part of the first day of advent of code 2025 for [input].
+    The solution for an empty input is [Error msg].
+    Requires: [input] to be a multiline string using `\n` as it's line separator. *)
diff --git a/ocaml/lib/year2025/day01/part02/turner.ml b/ocaml/lib/year2025/day01/part02/turner.ml
new file mode 100644
index 0000000..7477093
--- /dev/null
+++ b/ocaml/lib/year2025/day01/part02/turner.ml
@@ -0,0 +1,28 @@
+open Dial
+
+module Turner : sig
+  val turn : Dial.t -> int -> Dial.direction -> Dial.t * int
+  (** [turn dial direction] is the new state of the dial after turning [direction] on [dial] *)
+end = struct
+  (** [turn dial direction] is the new state of the dial after turning [direction] on [dial].
+      Raises: [dial_out_of_range] if the dial is moved to an invalid state. *)
+  let rec turn dial zero_count direction =
+    let open Dial in
+    match direction with
+    | Left 0 ->
+        (dial, zero_count)
+    | Left n ->
+        let dial' = prev dial in
+        let zero_count' =
+          if Dial.is_zero dial' then zero_count + 1 else zero_count
+        in
+        turn dial' zero_count' (Left (n - 1))
+    | Right 0 ->
+        (dial, zero_count)
+    | Right n ->
+        let dial' = next dial in
+        let zero_count' =
+          if Dial.is_zero dial' then zero_count + 1 else zero_count
+        in
+        turn dial' zero_count' (Right (n - 1))
+end
-- 
cgit v1.2.3